Gallantry_ver12

10 '=GALLANTRY= VER.1.2 BY YONAPUU,2024
20 GOTO 3160
30 'ｷｰﾆｭｳﾘｮｸ
40 K=9:Z$=INKEY$:IF Z$="W" THEN K=8
50 IF Z$="X" THEN K=2
60 IF Z$="A" THEN K=4
70 IF Z$="D" THEN K=6
80 IF Z$="-" THEN K=0
90 IF Z$="+" THEN K=1
100 IF Z$="3" THEN K=3
110 IF K=9 THEN 40
120 RETURN
130 'ﾌｨｰﾙﾄﾞ
140 CLS:ON U+1 GOSUB 1130,1160:BB=0
150 P=0:IF U=1 THEN U$=MID$(B$(Y+R),X,1):GOTO 190
160 U$=MID$(A$(Y+R),X,1):IF U$=CHR$(253) THEN X=S:Y=T
170 IF U$=CHR$(134) AND H=0 THEN X=S:Y=T
180 IF U$=CHR$(252) THEN P=.3
190 LOCATE 0,0:IF U=0 THEN 240
200 IF U$=CHR$(253) THEN X=S:Y=T
210 IF U$=CHR$(254) THEN X=S:Y=T
220 IF U$=CHR$(135) THEN X=S:Y=T
230 PRINT MID$(B$(Y),X-7,15);:LOCATE 0,1:PRINT MID$(B$(Y+1),X-7,15);:GOTO 310
240 IF X>8 THEN 270
250 PRINT MID$(A$(Y),49+X,8-X)+MID$(A$(Y),1,X+7);
260 LOCATE 0,1:PRINT MID$(A$(Y+1),49+X,8-X)+MID$(A$(Y+1),1,X+7);:GOTO 310
270 IF X<50 THEN 300
280 PRINT MID$(A$(Y),X-7)+MID$(A$(Y),1,X-49);
290 LOCATE 0,1:PRINT MID$(A$(Y+1),X-7);MID$(A$(Y+1),1,X-49);:GOTO 310
300 LOCATE 0,0:PRINT MID$(A$(Y),X-7,15);:LOCATE 0,1:PRINT MID$(A$(Y+1),X-7,15);
310 LOCATE 7,R:PRINT CHR$(255);:LOCATE 15,0:PRINT ":HP";A;"   ";
320 S=X:T=Y
330 'ｲﾄﾞｳﾎｶ
340 GOSUB 40:IF K<>8 THEN 380
350 IF R=0 THEN R=1:DEFCHR$(255)=P$(1)
360 Y=Y-1:IF Y=0 AND U=0 THEN Y=37
370 GOTO 1190
380 IF K<>2 THEN 420
390 IF R=1 THEN R=0:DEFCHR$(255)=P$(0)
400 Y=Y+1:IF Y>37 AND U=0 THEN Y=1
410 GOTO 1190
420 IF K<>4 THEN 450
430 X=X-1:IF X=0 AND U=0 THEN X=56
440 GOTO 1190
450 IF K<>6 THEN 480
460 X=X+1:IF X>56 AND U=0 THEN X=1
470 GOTO 1190
480 IF K=3 THEN GOSUB 2610:GOTO 140
490 IF K<>0 THEN 340
500 'ｱｼﾓﾄ
510 IF U=0 AND U$=CHR$(236) THEN 1850
520 IF U=0 AND U$=CHR$(134) THEN 1040
530 IF U<>0 OR U$<>CHR$(237) THEN 670
540 IF X=5 THEN X=8:Y=2:GOTO 630
550 IF X=18 THEN X=24:Y=2:GOTO 630
560 IF X=4 THEN X=37:Y=5:GOTO 630
570 IF X=15 THEN X=14:Y=26:GOTO 630
580 IF X=54 THEN X=25:Y=29:GOTO 630
590 IF X=53 THEN X=41:Y=22:GOTO 630
600 IF X=37 THEN X=17:Y=37:GOTO 630
610 IF X=20 THEN X=39:Y=32:GOTO 630
620 GOTO 670
630 U=1
640 IF Z(7)=1 THEN J=5
650 IF R=1 THEN Y=Y-1
660 S=X:T=Y:GOTO 140
670 IF U<>0 OR U$<>CHR$(238) THEN 770
680 IF Z(1)+Z(2)=2 AND X=12 THEN X=5:Y=17:J=1:GOTO 640
690 IF X=5 THEN X=12:Y=13:J=0:GOTO 640
700 IF Z(3)+Z(4)=2 AND X=33 THEN X=39:Y=24:J=2:GOTO 640
710 IF X=39 THEN X=33:Y=27:J=1:GOTO 640
720 IF Z(5)=1 AND X=52 THEN X=53:Y=21:J=3:GOTO 640
730 IF X=53 THEN X=52:Y=25:J=2:GOTO 640
740 IF Z(6)=1 AND X=43 THEN X=38:Y=17:J=4:GOTO 640
750 IF X=38 THEN X=43:Y=17:J=3:GOTO 640
760 LOCATE 15,0:PRINT ":ﾏﾀﾞ ﾂｶｴﾅｲ.";:GOSUB 4370:GOTO 150
770 IF U=0 THEN 140
780 IF U$=CHR$(227) THEN 930
790 IF U$=CHR$(134) THEN LOCATE 15,0:PRINT ":HPｶﾞ ｾﾞﾝｶｲｼﾀ!";:GOSUB 4370:A=B:GOTO 140
800 IF U$<>CHR$(252) THEN 830
810 B$(Y+R)=MID$(B$(Y+R),1,X-1)+" "+MID$(B$(Y+R),X+1)
820 I=INT((J+5)^3):F=F+I:LOCATE 15,0:PRINT I;CHR$(241);"!";:GOSUB 4370:GOTO 140
830 IF U$<>"?" THEN 150
840 W=22:BB=0:IF X=13 THEN BB=1
850 IF X=21 THEN BB=2
860 IF X=35 THEN BB=3
870 IF X=16 THEN BB=4
880 IF X=33 THEN BB=5
890 IF X=43 THEN BB=6
900 IF X=9 THEN BB=7
910 IF X=27 THEN BB=8
920 GOTO 1210
930 IF X=8 OR BB=1 THEN X=5:Y=3:GOTO 1020
940 IF X=24 OR BB=2 THEN X=18:Y=4:GOTO 1020
950 IF X=37 OR BB=3 THEN X=4:Y=20:GOTO 1020
960 IF X=14 OR BB=4 THEN X=15:Y=26:GOTO 1020
970 IF X=25 OR BB=5 THEN X=54:Y=33:GOTO 1020
980 IF X=41 OR BB=6 THEN X=53:Y=3:GOTO 1020
990 IF X=17 OR BB=7 THEN X=37:Y=4:GOTO 1020
1000 IF X=39 OR BB=8 THEN X=20:Y=35:GOTO 1020
1010 GOTO 150
1020 IF R=0 THEN Y=Y+1
1030 BB=0:U=0:GOTO 660
1040 IF X=19 AND Y+R=26 THEN 1100
1050 IF X=26 AND Y+R=12 THEN 1100
1060 IF X=31 AND Y+R=13 THEN 1100
1070 IF X=35 AND Y+R=14 THEN 1100
1080 IF X=49 AND Y+R=31 THEN 1100
1090 GOTO 150
1100 A$(Y+R)=MID$(A$(Y+R),1,X-1)+CHR$(254)+MID$(A$(Y+R),X+1):F=F+2E5
1110 LOCATE 15,0:PRINT 2E5;CHR$(241);"!";:GOSUB 4370:GOTO 140
1120 'ﾌｨｰﾙﾄﾞｷｬﾗｾｯﾃｲ
1130 DEFCHR$(252)="708E709C60":DEFCHR$(253)="06FA26720E":DEFCHR$(254)="0020000800"
1140 P$(0)="E024F8F824":P$(1)="127C7C1270":A$=CHR$(134):DEFCHR$(255)=P$(R):RETURN
1150 'ﾒｲｷｭｳｷｬﾗｾｯﾃｲ
1160 DEFCHR$(252)="FCA4BCA4FC":DEFCHR$(253)="FC4A7A4AFC":DEFCHR$(254)="54DC74DC54"
1170 A$=CHR$(134):B$=" ":C$=CHR$(227):E$="?":F$=CHR$(135):DEFCHR$(255)=P$(R):RETURN
1180 'ﾀﾀｶｲ
1190 IF RAN#+P<.95 THEN 150
1200 W=INT(RAN#*3)+J*4+U:IF W>22 THEN W=22
1210 RESTORE W*10+2800:FOR Q=0 TO 3:READ Z$(Q):NEXT Q:READ Q$,M,N,L:IF L=6 THEN L=INT(RAN#*6)
1220 IF LEN(Q$)=1 THEN Q$="ﾏｵｳ":IF BB=-2 THEN Q$="ｶﾞﾄ"
1230 CLS:FOR Q=0 TO 5:V(Q)=0:NEXT Q:O=N:RESTORE E*10+2720:READ K$,K$,K$,K$,K$
1240 IF W=22 AND BB<>0 THEN M=(BB+4)^2-6:N=BB^4+20:L=0:O=N
1250 RESTORE W*10+2800:GOSUB 2680:I=0:GOSUB 2550
1260 LOCATE 0,0:PRINT CHR$(252);CHR$(253);":["+Q$+"]:";N;"/HP";A;
1270 LOCATE 0,1:PRINT CHR$(254);CHR$(255);": ﾀﾀｶｳ ﾆｹﾞﾙ";:LOCATE 3+5*I,1:PRINT ">";
1280 GOSUB 40:IF K=4 THEN I=0
1290 IF K=6 THEN I=1
1300 IF K=3 THEN GOSUB 2610:GOTO 1250
1310 IF K<>1 THEN 1350
1320 GOSUB 2550:PRINT ":ｱﾅﾀ/ﾄﾞｸ";V(0);":ｷｮｳｶ";V(1);":ｴﾝﾏｸ";V(2);
1330 LOCATE 2,1:PRINT ":ﾃｷ /ﾄﾞｸ";V(3);":ｷｮｳｶ";V(4);":ｴﾝﾏｸ";V(5);
1340 GOSUB 4350:GOTO 1250
1350 IF K<>0 THEN 1270
1360 LOCATE 2,0:IF I=1 AND RAN#>.2 THEN GOSUB 2550:PRINT ":ｱﾅﾀﾊ ﾆｹﾞﾀﾞｼﾀ!";:GOSUB 4350:GOTO 140
1370 'ｽｷﾙ
1380 GOSUB 2550:I=INT(RAN#*100):P=0:IF I<J(0) THEN AA=0:GOSUB 1730:GOTO 1410
1390 FOR K=1 TO 5:P=P+J(K-1):IF I>P AND P+J(K)>=I THEN AA=K:K=9
1400 NEXT K:IF K>9 THEN GOSUB 1730
1410 PRINT ":ﾅｶﾏ["+K$+"]ﾉ["+J$(E)+"]!";:AA=E:GOSUB 1740
1420 IF V(0)>0 THEN A=A-V(0)*INT(B/6):GOSUB 2550:PRINT ":ﾄﾞｸｶﾞ ﾏﾜﾙ!";:GOSUB 1820:GOSUB 4350
1430 GOSUB 2550:LOCATE 2,0:PRINT ":ｱﾅﾀﾉ ｺｳｹﾞｷ!";:LOCATE 2,1
1440 IF V(2)*.45>RAN# THEN PRINT ":ｼｶｼ ｶﾜｻﾚﾃｼﾏｯﾀ!";:GOSUB 4350:GOTO 1590
1450 I=C*2+D:I=I+INT(RAN#*I/4+V(1)*.8*I:PRINT ":Hit!";I;:N=N-I:GOSUB 4350:IF N>0 THEN 1590
1460 'ｼｮｳﾘ
1470 PRINT ":["+Q$+"]ｦ ﾀｵｼﾀ!";:F=F+M*4:G=G+M:GOSUB 4350
1480 IF W<22 OR BB=0 THEN 140
1490 IF BB>7 OR BB<0 THEN 1530
1500 IF W<>22 OR BB=0 OR Z(BB)=1 THEN 1530
1510 Z(BB)=1:PRINT ":ｺﾞｳｵﾝ ｶﾞ ﾋﾋﾞｲﾀ.";:GOSUB 4350:IF BB=7 THEN H=1:PRINT "ﾌﾈｦ ﾃﾆｲﾚﾀ!";:GOSUB 4370
1520 GOTO 930
1530 IF BB=8 THEN BB=-1:K=9:I=12:GOSUB 4240:W=23:GOTO 1210
1540 IF BB=-1 THEN BB=-2:K=13:I=17:GOSUB 4240:W=24:GOTO 1210
1550 IF BB<>-2 THEN 140
1560 K=18:I=32:GOSUB 4240:CLS:PRINT "-=GALLANTRY=- (C)YONAPUU 2024";:LOCATE 0,1:PRINT "*THE END*";
1570 GOTO 1570
1580 'ﾃｷﾉ ﾀｰﾝ
1590 IF V(3)>0 THEN N=N-V(3)*INT(O/6):GOSUB 2550:PRINT ":["+Q$+"]ﾊ ﾄﾞｸｶﾞﾏﾜﾙ!";:GOSUB 4350:IF N<1 THEN 1470
1600 PRINT ":["+Q$+"]ﾉ ｺｳｹﾞｷ!";:LOCATE 2,1
1610 IF V(5)*.45>RAN# THEN PRINT ":ﾅﾝﾄｶ ｶﾜｼﾀ!";:GOSUB 4350:GOTO 1640
1620 I=M:I=I+INT(RAN#*I/4+V(4)*.8*I:LOCATE 2,1:PRINT ":Dam!";I;
1630 A=A-I:GOSUB 4350:GOSUB 1820
1640 PRINT ":ﾃｷﾉ["+J$(L)+"]!";
1650 IF L=0 THEN N=N+INT(O/5):IF N>O THEN N=O
1660 IF L=1 THEN V(0)=V(0)+1:IF V(0)>3 THEN V(0)=3
1670 IF L=2 THEN V(3)=0
1680 IF L=3 THEN V(4)=V(4)+1:IF V(4)>2 THEN V(4)=2
1690 IF L=4 THEN V(2)=V(2)+1:IF V(2)>2 THEN V(2)=2
1700 IF L=5 THEN V(5)=0
1710 GOSUB 4350:GOTO 1260
1720 'ｱﾅﾀﾉ ｽｷﾙ
1730 PRINT ":ｽｷﾙ["+J$(AA)+"]!";
1740 IF AA=0 THEN A=A+INT(B/5):IF A>B THEN A=B
1750 IF AA=1 THEN V(3)=V(3)+1:IF V(3)>3 THEN V(3)=3
1760 IF AA=2 THEN V(0)=0
1770 IF AA=3 THEN V(1)=V(1)+1:IF V(1)>2 THEN V(1)=2
1780 IF AA=4 THEN V(5)=V(5)+1:IF V(5)>2 THEN V(5)=2
1790 IF AA=5 THEN V(2)=0
1800 GOTO 4350
1810 'ｼﾎﾞｳﾊﾝﾃｲ
1820 IF A>0 THEN RETURN
1830 GOSUB 2550:PRINT ":ｱﾅﾀﾊ ﾏｹﾀ...":CLS:U=0:X=5:Y=12:S=X:T=Y:J=0:GOTO 640
1840 'ﾏﾁ
1850 CLS:RESTORE 3140:GOSUB 2680
1860 IF X=5 THEN Q=1
1870 IF X=7 THEN Q=2
1880 IF X=23 THEN Q=3
1890 IF X=42 THEN Q=4
1900 IF X=48 THEN Q=5
1910 IF X=35 THEN Q=6
1920 IF X=4 THEN Q=7
1930 IF X=26 THEN Q=8
1940 LOCATE 0,0:PRINT CHR$(252);CHR$(253);:LOCATE 0,1:PRINT CHR$(254);CHR$(255);
1950 L=Q:RESTORE L*10+3050:READ W$,M$(0),N(0),M$(1),N(1)
1960 'ﾏﾁﾒｲﾝ
1970 I=0
1980 LOCATE 3,0:PRINT "[";W$;"ﾉﾏﾁ]:ｵｶﾈ";F;CHR$(241);:LOCATE 3,1:PRINT "  ﾌﾞｷﾔ ﾔﾄﾞﾔ ｼﾞｲﾝ ﾓﾄﾞﾙ";:LOCATE I*5+4,1:PRINT ">";
1990 GOSUB 40:LOCATE I*5+4,1:PRINT " ";
2000 IF K=4 THEN I=I-SGNI
2010 IF K=6 THEN I=I+SGN(3-I)
2020 IF K=3 THEN GOSUB 2610:GOTO 1850
2030 IF K<>0 THEN 1980
2040 IF I=3 THEN 140
2050 GOSUB 2550:ON I GOTO 2160,2320
2060 'ﾌﾞｷﾔ
2070 LOCATE 3,0:PRINT " "+M$(0);N(0);CHR$(241);:LOCATE 3,1:PRINT " ";M$(1);N(1);CHR$(241);
2080 LOCATE 3,I:PRINT ">";:GOSUB 40
2090 IF K=8 THEN I=0:GOTO 2070
2100 IF K=2 THEN I=1:GOTO 2070
2110 IF K=1 THEN GOSUB 2550:GOTO 1970
2120 IF K<>0 THEN 2080
2130 IF INT(SQR N(I))>D AND F>=N(I) THEN D=INT(SQR N(I)):F=F-N(I):D$=M$(I):GOSUB 2550:LOCATE 3,0:PRINT "ｺｳﾆｭｳ!";:GOSUB 4350
2140 GOTO 2070
2150 'ﾔﾄﾞﾔ
2160 I=0
2170 GOSUB 2550
2180 LOCATE 3,0:PRINT " ｼｭｸﾊｸ";3^L;CHR$(241);:LOCATE 3,1:PRINT " ﾅｶﾏﾍﾝｺｳ";
2190 LOCATE 3,I:PRINT ">";:GOSUB 40:IF K=8 THEN I=0:GOTO 2180
2200 IF K=2 THEN I=1:GOTO 2180
2210 IF K=1 THEN 1970
2220 IF K<>0 THEN 2170
2230 IF I=0 AND F>=3^L THEN F=F-3^L:GOSUB 2550:LOCATE 3,0:PRINT "ｸﾞｳｸﾞｳ...";:A=B:GOSUB 4350
2240 IF I<>1 THEN 1970
2250 I=0:GOSUB 2550:RESTORE E*10+2720:GOSUB 2680:READ K$
2260 LOCATE 3,0:PRINT ":ﾅｶﾏｦ ｴﾗﾝﾃﾞｸﾀﾞｻｲ.";:LOCATE 3,1:PRINT " >[";K$;"]:";J$(E);:GOSUB 40
2270 IF K=6 THEN E=E+1:IF E>5 THEN E=0
2280 IF K=4 THEN E=E-1:IF E<0 THEN E=5
2290 IF K=1 THEN 1850
2300 GOTO 2250
2310 'ｼﾞｲﾝ
2320 I=0
2330 LOCATE 3,0:PRINT " ﾚﾍﾞﾙｱｯﾌﾟ";:LOCATE 3,1:PRINT " ﾜﾘｱｲﾍﾝｺｳ";:LOCATE 3,I:PRINT ">";:GOSUB 40
2340 IF K=8 THEN I=0:GOTO 2330
2350 IF K=2 THEN I=1:GOTO 2330
2360 IF K=1 THEN 1970
2370 IF K<>0 THEN 2330
2380 GOSUB 2550:LOCATE 3,0:K=2^C+12:IF K>2060 THEN K=2060
2390 IF I=0 AND G>=K THEN G=0:C=C+1:PRINT "ﾚﾍﾞﾙｶﾞ ｱｶﾞｯﾀ!";:B=B+C^2:GOSUB 4350:GOTO 2330
2400 IF I=0 THEN GOSUB 2550:PRINT " ﾂｷﾞﾊ";K;:GOSUB 4350:GOTO 2330
2410 'ﾜﾘｱｲﾍﾝｺｳ
2420 I=0
2430 GOSUB 2590:W=J(0)+J(1)+J(2)+J(3)+J(4)+J(5)
2440 P=3:GOSUB 2530:PRINT ">";:GOSUB 40
2450 P=8:GOSUB 2530
2460 IF K=8 THEN IF J(I)<99 AND W<99 THEN J(I)=J(I)+4:W=W+4:PRINT J(I);" ";
2470 IF K=2 THEN IF J(I)>1 AND W>1 THEN J(I)=J(I)-4:W=W-4:PRINT J(I);" ";
2480 IF K=6 THEN P=3:GOSUB 2530:PRINT " ";:I=I+SGN(5-I
2490 IF K=4 THEN P=3:GOSUB 2530:PRINT " ";:I=I-SGNI
2500 IF K=1 THEN IF J(0)+J(1)+J(2)+J(3)+J(4)+J(5)=100 THEN GOSUB 2550:I=0:GOTO 1970
2510 IF K<>0 THEN 2440
2520 FOR P=0 TO 5:J(P)=0:NEXT P:GOTO 2430
2530 LOCATE 9*I-27*INT(I/3)+P,I/3:RETURN
2540 'ｶﾞﾒﾝｸﾘｱ
2550 LOCATE 2,0:PRINT "                              ";
2560 LOCATE 2,1:PRINT "                             ";
2570 LOCATE 2,0:RETURN
2580 'ﾜﾘｱｲﾋｮｳｼﾞ
2590 FOR P=0 TO 5:LOCATE P*9-27*INT(P/3)+4,P/3:PRINT J$(P);J(P);:NEXT P:RETURN
2600 'ｼﾞｮｳﾀｲﾋｮｳｼﾞ
2610 CLS:PRINT "LV";C;"EXP";G;:LOCATE 0,1:PRINT "HP";A;"/";B
2620 CLS:PRINT "ｵｶﾈ";F;CHR$(241);:LOCATE 0,1:PRINT D$;"=ｲﾘｮｸ";D
2630 CLS:RESTORE 2710:GOSUB 2680:GOSUB 2590:STOP
2640 CLS:RESTORE E*10+2720:GOSUB 2680:READ K$
2650 LOCATE 3,0:PRINT " ﾅｶﾏ=["+K$+"] "+J$(E)
2660 CLS:RETURN
2670 'ｷｬﾗﾋｮｳｼﾞ
2680 FOR Q=0 TO 3:READ Z$(Q):DEFCHR$(252+Q)=Z$(Q):NEXT Q:LOCATE 0,0:PRINT CHR$(252);CHR$(253);
2690 LOCATE 0,1:PRINT CHR$(254);CHR$(255);:RETURN
2700 'ｷｬﾗﾃﾞｰﾀ
2710 DATA F836549654,30D436141E,7E120A0414,D4040E34C2,ｱﾅﾀ
2720 DATA 7EFEFCF2FA,F8F0FA7E3E,9E186482E0,0400E284F8,ﾏﾘ
2730 DATA 7E26E82E00,202EA8661C,0804041212,940810E000,ｶｲﾝ
2740 DATA 2242868A90,908A864222,F884C6C20A,0A82C6C4F8,ﾙｶ
2750 DATA 3E608E1E62,063A8C423E,E03E88C48A,8AC4883EE0,ﾛｲ
2760 DATA 0002041860,3456201CE2,7CC4341208,0E0C4AF000,ﾙｴﾙ
2770 DATA 6094CC2EC8,C82CD4D638,0804021212,860830C000,ﾗﾑ
2780 DATA 3E7EFCF4F6,D4F6FE7E3E,FEFE3E0E2E,AE1EFEFEEE,ﾏｵｳ
2790 'ﾏﾓﾉﾃﾞｰﾀ
2800 DATA 0044022E2E,0E0E1C5C00,0078FCFCF8,F8FCFC9C00,ｽﾗｲﾑ,3,6,0
2810 DATA 70A886A870,504826100E,0038140A0A,0A12E408F0,ｽﾈｰｸ,5,9,0
2820 DATA 2814FA1E2E,2E1EFA1428,608EF0F854,54F8F08E60,ｽﾊﾟｲﾀﾞｰ,10,18,0
2830 DATA 003E409880,98807E0000,00F0482442,4222C44CF0,ｺﾞｰｽﾄ,14,32,0
2840 DATA 060E162242,505040A2FC,5C445C44FC,686868A828,ｺﾎﾞﾙﾄ,22,72,1
2850 DATA 02C4FCA216,162282FCC2,884422944A,468812262E,ｺﾞﾌﾞﾘﾝ,28,110,1
2860 DATA 0E30468E80,808E46300E,C03E2E3AAE,AE3A2E3EC0,ｽｶﾙ,36,135,1
2870 DATA FE00FE7896,8292924638,FE50D4DEFE,FEFEFEFE80,ﾅｲﾄ,44,160,1
2880 DATA 0808707070,700A0A0A06,10224488F0,C070F874CA,ﾃﾞｭﾗﾊﾝ,52,190,3
2890 DATA 867008B44A,94864AB202,008E78080E,101010FE40,ｵｰｸ,64,240,3
2900 DATA 9098462014,1420469890,4488929458,4098949248,ﾃﾞﾋﾞﾙ,81,290,3
2910 DATA 0040E2F6E2,767EFEBE7E,AE9E9E9CFE,A0A0A0A0A0,ﾘｻﾞｰﾄﾞﾏﾝ,92,360,3
2920 DATA 709C969C70,3E707C703E,00E0BEE0FE,FEFEFEFEFE,ﾒｲｼﾞ,100,430,4
2930 DATA F08C621806,3E56C2563E,00000E70F8,E4BC68BC54,ｻﾑﾗｲ,110,530,4
2940 DATA CCBCAC5454,5454ACBCCC,080E0C1830,D28E4244F8,ﾎﾌﾞｺﾞﾌﾞ,123,600,4
2950 DATA 02C4447CA8,A87C44C402,98423E86A6,A6863E4298,ﾐﾉﾀｳﾛｽ,140,700,4
2960 DATA 1AE65252E6,0200FE807E,A0A080FEFE,FEFEF0B8E0,ｵｰｶﾞ,158,820,0
2970 DATA 2422207088,8870202224,867E8204BA,BA04827E86,ｺﾞｰﾚﾑ,180,900,1
2980 DATA 80C6A8582E,123252EE80,62AE7204B8,503826F20E,ﾄﾞﾗｺﾞﾝ,200,1E3,3
2990 DATA 0E30408092,809440300E,906478203C,3C20786490,ﾄﾛｲﾄﾞ,220,1200,4
3000 DATA 9C62AE8A8E,BE222E222E,4A6A4C7800,0080407E80,ﾃﾞｰﾓﾝ,240,1300,6
3010 DATA 78DEDEDE7E,3E3E3A3A3C,0EF2FEFA8A,3A7EFEC0FE,ﾆﾝｼﾞｬ,260,1400,6
3020 DATA 344A9A4A1E,484048201E,681E101E68,2620204080,ｶﾞｰﾃﾞｨｱﾝ,200,1300,6
3030 DATA 0E3EE8E2E8,16F288E082,FEFEFEFEFE,FEFEFEF0C0,!,280,4E3,6
3040 DATA 12086C9290,680E102020,0638C29C60,9C62188680,?,310,7E3,6
3050 'ﾏﾁﾃﾞｰﾀ
3060 DATA ｱﾙｼｱ,ﾑﾁ,30,ﾅｲﾌ,400
3070 DATA ﾙﾍﾞ,ｺﾝﾎﾞｳ,800,ﾄﾞｳﾉｹﾝ,1300
3080 DATA ｶﾞｳ,ﾄﾞｳﾉﾔﾘ,1800,ﾕﾐﾔ,3E3
3090 DATA ｳﾞｪﾑ,ｸｻﾘｶﾞﾏ,5E3,ﾃﾂﾉｹﾝ,8E3
3100 DATA ｾﾞｸ,ﾃﾂﾉﾔﾘ,12E3,ﾊｶﾞﾈﾉｹﾝ,15E3
3110 DATA ﾗﾌﾟﾂ,ﾎﾉｵﾉｹﾝ,2E4,ｺｵﾘﾉｹﾝ,24E3
3120 DATA ｸﾞﾘ-,ﾗｲﾒｲｹﾝ,4E4,ﾀﾂﾏｷｹﾝ,68E3
3130 DATA ﾗｽﾄ,ﾘｭｳﾉｹﾝ,1E5,ｾｲﾅﾙｹﾝ,1E6
3140 DATA 040E140E36,627E121212,0AFA0AFA10,1012F2F212
3150 'ｻｲｼｮ
3160 INPUT "9=ｻｲｼｮｶﾗ,ﾎｶ=ﾂﾂﾞｷｶﾗ",Z$:IF Z$<>"9" THEN 140
3170 'ｼｮｷｾｯﾃｲ
3180 CLEAR:CLS:DIM A$(39):DIM J$(7):DIM P$(2):DIM J(7):DIM M$(2):DIM N(2):DIM H$(2):DIM B$(49)
3190 DIM Z$(4):DIM Z(9):DIM V(6):X=5:Y=12:A=24:B=A:GOSUB 1130
3200 'ﾏｯﾌﾟﾃﾞｰﾀﾉｻｸｾｲ
3210 B$=CHR$(252):C$=CHR$(253):D$=CHR$(254)
3220 F$=A$+A$:G$=F$+F$:H$=G$+G$
3230 I$=B$+B$:J$=I$+I$:K$=J$+J$
3240 L$=C$+C$:M$=L$+L$:N$=M$+M$
3250 O$=D$+D$:P$=O$+O$:Q$=P$+P$
3260 R$=CHR$(236):S$=CHR$(237):T$=CHR$(238)
3270 CLS:PRINT "(C)YONAPUU,2024";
3280 A$(1)=H$+H$+H$+H$+H$+H$+H$
3290 A$(2)=A$(1):A$(38)=A$(1)
3300 A$(3)=F$+A$+Q$+O$+D$+H$+Q$+D$+G$+Q$+H$+P$+A$
3310 A$(4)=F$+O$+S$+Q$+P$+O$+F$+D$+I$+D$+R$+P$+D$+F$+A$+D$+J$+I$+L$+C$+G$+A$+O$+D$+S$+O$+A$
3320 A$(5)=F$+P$+D$+C$+O$+C$+I$+P$+S$+D$+F$+J$+I$+B$+O$+F$+O$+I$+S$+J$+M$+F$+A$+O$+D$+C$+P$
3330 A$(6)=F$+P$+D$+M$+C$+I$+P$+D$+F$+D$+I$+B$+P$+F$+P$+J$+I$+M$+F$+O$+D$+M$+L$
3340 A$(7)=F$+P$+M$+L$+I$+P$+G$+P$+G$+M$+L$+C$+I$+B$+M$+F$+A$+P$+M$+C$
3350 A$(8)=F$+O$+I$+B$+L$+C$+J$+O$+H$+G$+O$+N$+C$+I$+O$+D$+F$+A$+O$+D$+I$+M$
3360 A$(9)=F$+O$+D$+I$+M$+C$+B$+O$+G$+A$+P$+O$+D$+J$+I$+M$+L$+I$+B$+D$+F$+A$+O$+D$+J$+I$+A$
3370 A$(10)=F$+O$+D$+B$+M$+L$+B$+O$+F$+A$+P$+O$+L$+K$+B$+L$+C$+J$+A$+F$+O$+R$+O$+D$+I$+B$+F$
3380 A$(11)=F$+A$+O$+I$+B$+L$+D$+C$+O$+D$+F$+P$+M$+L$+B$+C$+K$+J$+B$+F$+A$+Q$+O$+A$
3390 A$(12)=F$+A$+D$+R$+D$+B$+D$+F$+P$+F$+A$+P$+D$+L$+C$+A$+M$+K$+I$+B$+F$+A$+C$+D$+C$+D$+C$+D$+C$+P$+A$
3400 A$(13)=F$+A$+P$+D$+F$+D$+T$+D$+G$+P$+O$+I$+F$+L$+C$+A$+L$+C$+A$+C$+J$+F$+A$+N$+C$+O$+D$+A$
3410 A$(14)=F$+A$+P$+F$+A$+O$+D$+G$+A$+P$+O$+J$+M$+L$+A$+M$+C$+F$+N$+L$+O$+D$+B$
3420 A$(15)=H$+H$+G$+A$+P$+J$+B$+M$+L$+D$+L$+C$+F$+O$+D$+L$+C$+D$+L$+O$+D$+I$
3430 A$(16)=F$+A$+P$+O$+L$+G$+P$+D$+G$+O$+I$+B$+M$+L$+P$+F$+O$+J$+C$+P$+D$+I$+B$
3440 A$(17)=F$+A$+D$+T$+O$+B$+M$+B$+Q$+G$+J$+B$+L$+C$+P$+T$+D$+A$+O$+T$+J$+I$+P$+I$+B$
3450 A$(18)=F$+O$+D$+J$+B$+C$+J$+P$+D$+I$+G$+I$+B$+L$+C$+O$+R$+P$+A$+O$+J$+I$+B$+P$+D$+I$
3460 A$(19)=F$+D$+K$+I$+B$+P$+O$+D$+I$+G$+J$+L$+P$+D$+F$+O$+D$+I$+B$+L$+P$+O$+B$+A$
3470 A$(20)=F$+O$+J$+M$+J$+B$+P$+O$+D$+G$+J$+I$+B$+O$+G$+O$+D$+B$+L$+C$+P$+O$+D$+A$
3480 A$(21)=F$+D$+S$+D$+I$+B$+M$+B$+L$+B$+L$+P$+O$+D$+G$+A$+J$+O$+G$+F$+A$+O$+M$+O$+D$+T$+D$+F$
3490 A$(22)=F$+O$+D$+J$+M$+L$+B$+L$+P$+O$+D$+G$+A$+P$+D$+F$+P$+G$+F$+A$+C$+P$+D$+F$
3500 A$(23)=F$+A$+O$+B$+R$+I$+N$+L$+Q$+G$+O$+D$+F$+P$+O$+H$+G$+F$
3510 A$(24)=G$+O$+I$+B$+N$+L$+Q$+L$+D$+G$+F$+O$+T$+P$+D$+F$+A$+O$+J$+B$+F$
3520 A$(25)=G$+A$+O$+M$+C$+J$+A$+L$+C$+B$+P$+M$+L$+D$+G$+O$+D$+I$+B$+O$+D$+M$+I$+T$+I$+B$+A$
3530 A$(26)=G$+F$+A$+M$+C$+O$+D$+B$+G$+B$+D$+R$+O$+D$+M$+C$+O$+D$+F$+P$+J$+D$+M$+J$+I$+D$
3540 A$(27)=F$+A$+O$+D$+F$+A$+P$+D$+S$+I$+F$+A$+B$+P$+D$+M$+B$+D$+T$+O$+F$+A$+O$+J$+D$+M$+C$+J$+B$+D$
3550 A$(28)=F$+O$+S$+O$+F$+A$+P$+O$+I$+A$+B$+P$+O$+M$+I$+P$+F$+A$+P$+I$+D$+M$+J$+F$
3560 A$(29)=F$+P$+O$+D$+G$+A$+P$+B$+P$+O$+M$+L$+I$+P$+F$+A$+Q$+L$+I$+B$+O$+D$
3570 A$(30)=F$+P$+D$+C$+O$+C$+O$+F$+A$+Q$+D$+M$+L$+I$+P$+F$+A$+C$+D$+C$+D$+C$+O$+I$+P$+O$+D$
3580 A$(31)=F$+P$+D$+M$+L$+C$+D$+G$+Q$+L$+J$+P$+D$+F$+M$+C$+D$+B$+F$+B$+O$+M$
3590 A$(32)=F$+P$+N$+C$+O$+F$+A$+P$+O$+D$+J$+B$+P$+D$+F$+A$+M$+C$+D$+B$+F$+B$+D$+M$+C$
3600 A$(33)=F$+P$+D$+M$+L$+C$+B$+P$+F$+A$+P$+D$+J$+P$+D$+G$+J$+C$+O$+I$+O$+D$+B$+D$+B$+D$
3610 A$(34)=F$+Q$+M$+I$+P$+D$+F$+P$+D$+I$+P$+D$+G$+J$+B$+Q$+D$+S$+O$
3620 A$(35)=F$+D$+R$+O$+K$+J$+P$+F$+A$+Q$+G$+A$+I$+B$+R$+I$+Q$+B$+D$+B$+D$
3630 A$(36)=F$+O$+D$+K$+J$+I$+S$+O$+D$+H$+G$+F$+A$+J$+B$+Q$+P$+D$
3640 A$(37)=F$+A$+O$+D$+K$+I$+B$+P$+O$+H$+H$+I$+P$+D$+G$+F$+O$+D$+A$
3650 'ﾒｲｷｭｳﾃﾞｰﾀﾉｻｸｾｲ
3660 GOSUB 1160:I$=CHR$(252):G$=CHR$(253):H$=CHR$(254)
3670 J$=F$+F$:K$=J$+J$:L$=K$+J$+F$
3680 M$=H$+H$:N$=M$+M$
3690 O$=B$+B$:P$=O$+O$
3700 CLS:PRINT "-=GALLANTRY=-";
3710 B$(0)=L$+L$+L$+L$+L$+L$+L$+L$+L$
3720 B$(1)=L$+G$+N$+G$+L$+G$+J$+H$+F$+H$+F$+L$+G$+F$+N$+H$+G$+L$
3730 B$(2)=L$+C$+P$+B$+L$+E$+J$+C$+F$+I$+F$+L$+I$+F$+P$+B$+I$+L$
3740 B$(3)=L$+B$+J$+B$+F$+B$+L$+O$+F$+B$+G$+B$+G$+L$+B$+J$+F$+B$+J$+F$+L$
3750 B$(4)=L$+B$+F$+H$+B$+H$+B$+L$+F$+B$+F$+P$+L$+B$+G$+H$+G$+B$+G$+H$+G$+L$
3760 B$(5)=L$+B$+F$+I$+O$+F$+L$+G$+B$+F$+B$+J$+F$+L$+O$+C$+P$+B$+L$
3770 B$(6)=L$+B$+K$+H$+L$+O$+F$+B$+G$+H$+G$+L$+B$+J$+F$+B$+F$+B$+F$+L$
3780 B$(7)=L$+B$+G$+M$+G$+I$+L$+B$+J$+P$+L$+B$+F$+H$+F$+A$+F$+B$+G$+L$
3790 B$(8)=L$+P$+O$+L$+B$+H$+F$+B$+F$+B$+F$+L$+I$+G$+I$+G$+J$+O$+L$
3800 B$(9)=L$+B$+F$+B$+F$+B$+F$+L$+O$+F$+I$+H$+B$+H$+L$+F$+O$+B$+M$+F$+B$+L$
3810 B$(10)=L$+B$+F$+B$+F$+B$+F$+L$+F$+B$+J$+O$+B$+L$+G$+B$+F$+O$+B$+H$+B$+L$
3820 B$(11)=L$+F$+H$+B$+F$+B$+F$+L$+G$+B$+H$+F$+B$+F$+B$+L$+O$+J$+F$+O$+B$+L$
3830 B$(12)=L$+F$+O$+F$+B$+H$+L$+O$+B$+G$+B$+F$+B$+L$+B$+J$+M$+B$+F$+B$+L$
3840 B$(13)=L$+F$+I$+J$+B$+E$+L$+I$+F$+O$+B$+H$+I$+L$+E$+J$+I$+O$+F$+B$+L$
3850 B$(14)=B$(0)
3860 B$(15)=L$+G$+F$+N$+M$+G$+L$+G$+K$+N$+G$+L$+G$+F$+M$+F$+H$+F$+M$+H$+G$+L$
3870 B$(16)=L$+A$+H$+P$+O$+B$+L$+I$+G$+H$+G$+F$+P$+B$+L$+I$+H$+E$+B$+H$+A$+H$+P$+L$
3880 B$(17)=L$+O$+B$+K$+F$+E$+L$+P$+F$+I$+F$+B$+F$+E$+L$+O$+F$+P$+B$+J$+B$+L$
3890 B$(18)=L$+F$+B$+F$+H$+K$+F$+L$+J$+F$+B$+J$+F$+B$+J$+L$+F$+B$+K$+B$+F$+M$+B$+L$
3900 B$(19)=L$+F$+B$+H$+B$+F$+G$+M$+G$+L$+M$+F$+B$+G$+H$+G$+B$+M$+L$+G$+B$+G$+H$+G$+F$+I$+H$+O$+B$+L$
3910 B$(20)=L$+H$+O$+B$+F$+I$+O$+B$+L$+B$+A$+F$+P$+O$+B$+L$+P$+B$+J$+F$+B$+J$+L$
3920 B$(21)=L$+I$+F$+B$+K$+F$+B$+L$+B$+K$+B$+J$+F$+B$+L$+B$+F$+B$+F$+B$+F$+M$+B$+M$+L$
3930 B$(22)=L$+B$+H$+B$+F$+M$+F$+H$+B$+L$+B$+G$+M$+G$+B$+F$+H$+F$+B$+L$+C$+G$+B$+F$+I$+F$+P$+B$+L$
3940 B$(23)=L$+O$+B$+F$+I$+B$+F$+O$+L$+P$+O$+F$+I$+F$+B$+L$+F$+O$+J$+F$+B$+K$+L$
3950 B$(24)=L$+B$+J$+H$+F$+B$+F$+B$+F$+L$+J$+B$+K$+B$+F$+B$+L$+H$+B$+F$+G$+H$+G$+B$+F$+G$+H$+G$+L$
3960 B$(25)=L$+B$+H$+F$+B$+F$+B$+H$+B$+F$+L$+H$+F$+B$+G$+M$+G$+B$+G$+B$+L$+O$+G$+P$+F$+O$+B$+L$
3970 B$(26)=L$+O$+F$+B$+F$+B$+C$+B$+H$+L$+I$+F$+P$+P$+L$+B$+F$+O$+J$+B$+F$+I$+F$+B$+L$
3980 B$(27)=L$+F$+B$+G$+B$+F$+B$+F$+O$+L$+B$+J$+F$+B$+J$+B$+J$+L$+B$+G$+B$+F$+M$+B$+J$+F$+B$+L$
3990 B$(28)=L$+G$+O$+B$+G$+B$+J$+B$+L$+B$+G$+H$+G$+B$+H$+F$+B$+M$+L$+O$+B$+H$+O$+B$+G$+H$+G$+B$+L$
4000 B$(29)=L$+I$+B$+F$+O$+B$+J$+I$+L$+B$+C$+P$+F$+O$+I$+L$+I$+F$+O$+B$+F$+P$+B$+L$
4010 B$(30)=B$(0)
4020 B$(31)=L$+G$+M$+F$+M$+F$+M$+H$+F$+G$+L$+G$+F$+M$+H$+F$+M$+H$+F$+M$+G$+L$
4030 B$(32)=L$+O$+A$+F$+B$+I$+F$+O$+B$+F$+I$+L$+I$+F$+O$+B$+H$+O$+B$+F$+O$+C$+L$
4040 B$(33)=L$+B$+J$+F$+B$+J$+B$+F$+B$+H$+B$+L$+B$+F$+B$+F$+O$+B$+F$+B$+F$+B$+J$+L$
4050 B$(34)=L$+B$+G$+H$+G$+O$+F$+B$+F$+O$+B$+L$+B$+H$+B$+H$+J$+B$+F$+B$+H$+B$+M$+L$
4060 B$(35)=L$+P$+O$+H$+B$+J$+F$+B$+L$+P$+H$+F$+B$+F$+P$+B$+L$
4070 B$(36)=L$+F$+B$+F$+B$+F$+O$+B$+F$+M$+B$+L$+J$+F$+B$+I$+F$+B$+F$+B$+F$+B$+F$+B$+L$
4080 B$(37)=L$+H$+B$+F$+B$+H$+B$+F$+B$+F$+C$+O$+L$+G$+H$+G$+J$+F$+B$+F$+B$+H$+I$+H$+B$+L$
4090 B$(38)=L$+O$+F$+O$+B$+H$+B$+J$+F$+B$+L$+O$+B$+G$+H$+G$+B$+H$+O$+F$+O$+L$
4100 B$(39)=L$+B$+J$+B$+F$+O$+B$+G$+H$+G$+B$+L$+B$+F$+P$+O$+F$+B$+F$+B$+F$+L$
4110 B$(40)=L$+B$+J$+I$+H$+B$+F$+P$+B$+L$+I$+H$+F$+B$+J$+F$+B$+F$+I$+F$+B$+F$+L$
4120 B$(41)=L$+B$+E$+J$+B$+F$+H$+F$+B$+J$+F$+L$+F$+I$+F$+B$+G$+H$+G$+B$+K$+F$+L$
4130 B$(42)=L$+J$+F$+H$+B$+F$+I$+F$+B$+G$+H$+G$+L$+F$+B$+F$+P$+B$+M$+J$+F$+L$
4140 B$(43)=L$+M$+O$+B$+F$+B$+G$+P$+L$+H$+B$+H$+B$+J$+F$+O$+B$+G$+H$+G$+L$
4150 B$(44)=L$+I$+O$+F$+B$+F$+O$+B$+J$+B$+L$+P$+G$+H$+G$+J$+P$+L$
4160 B$(45)=L$+J$+F$+H$+B$+H$+F$+B$+F$+M$+B$+L$+K$+O$+B$+H$+K$+B$+L$
4170 B$(46)=L$+M$+H$+O$+B$+H$+B$+H$+O$+B$+L$+G$+M$+G$+B$+F$+O$+G$+M$+G$+B$+L$
4180 B$(47)=L$+I$+O$+B$+F$+P$+B$+F$+I$+L$+E$+P$+J$+P$+O$+L$
4190 B$(48)=B$(0)
4200 D$="ｽﾃﾞ":D=1:C=1:U=0:J(0)=100
4210 J$(0)="ｶｲﾌｸ":J$(1)="ﾄﾞｸ":J$(2)="ｹｯｾｲ":J$(3)="ｷｮｳｶ":J$(4)="ｴﾝﾏｸ":J$(5)="ｶｾﾞ"
4220 K=1:I=8:CLS:GOSUB 4240:K$="ﾏﾘ":GOTO 140
4230 'ﾒｯｾｰｼﾞﾋｮｳｼﾞ
4240 FOR M=K TO I:RESTORE M*10+4380:READ Z$:L=LEN(Z$):FOR P=1 TO L
4250 U$=MID$(Z$,P,1):IF U$="M" THEN CLS:GOTO 4330
4260 IF U$<"E" OR U$>"L" THEN 4280 
4270 N=ASC(U$)-69:RESTORE N*10+2710:GOSUB 2680:READ K$:LOCATE 3,0:PRINT K$;":";:GOTO 4330
4280 IF U$="A" THEN U$=CHR$(224) ELSE IF U$="B" THEN U$=CHR$(225)
4290 IF U$="C" THEN U$=CHR$(226) ELSE IF U$="?" THEN U$="B"
4300 IF U$="-" THEN U$=CHR$(176)
4310 U$=CHR$(ASC(U$)-3):IF P=27 THEN LOCATE 3,1
4320 PRINT U$;
4330 NEXT P:GOSUB 4370:CLS:NEXT M:RETURN
4340 'ｼﾞｶﾝｶｾｷﾞ1
4350 FOR I=200 TO 1 STEP -1:NEXT I:GOSUB 2550:LOCATE 2,0:RETURN
4360 'ｼﾞｶﾝｶｾｷﾞ2
4370 FOR I=500 TO 1 STEP -1:NEXT I:CLS:RETURN
4380 'ｶｲﾜﾃﾞｰﾀ
4390 DATA ｴﾈﾃﾍ#ﾐBｲﾇBﾌ#ｶｷﾆB#ﾕｾBﾕﾃ1
4400 DATA Eｽｽﾍ#ﾇBｽﾃB?#ﾈﾁBﾃB#ﾈﾉﾖ#ｸﾖｵﾃBﾁﾈｵ111
4410 DATA Fﾙｹｲﾃ#ｺｹB#ﾅｵﾃﾌﾋ1ﾟﾃｿﾍ#ﾒﾛ1ｼｹBｿﾆ#ﾃｸﾝﾆｵﾃ#ｴﾈﾃｩ#ﾓﾅｼﾃﾌ1
4420 DATA Gｵﾒﾍ#ﾒｸｶｹB#ﾎﾇﾇﾌ#ﾁAﾂｶﾉ#ｹｲﾆ#ﾁｹｵｩ#ｺｱｶﾏﾆB#ｿﾍｵｿﾆｵﾜAﾃB1
4430 DATA Hｺﾓﾖ#ﾁAｿﾌ#ﾙｶﾃBｹﾚ#ﾟﾃｿﾃﾄ#ﾝｿBﾀﾃAﾀﾌ#ｵﾄｵAﾇｿﾆ#ﾃﾃｹｵﾃﾒｷ1
4440 DATA Iｸﾝｾﾒﾃﾄﾍ#ﾗﾇBﾗﾉ#ｵﾜ1ｵﾅﾆBﾖ#ｿB-AﾎBﾍ#ﾆBｺﾆﾜｹﾚﾈ1
4450 DATA Jﾀｺﾜﾌ#ﾟﾛｴｵﾖ#ｽﾒﾕﾉ#ｹｷﾜAﾃB1ｴﾒｻ#ﾓﾆｵﾜﾇ#ｿｲﾐCｹBｷｿｩ#ｻﾚｶﾂB1
4460 DATA Kﾟﾝﾟﾝﾌ#ﾋAｹBAﾍ#ﾒｸｶﾃBﾇｶﾃB$#ﾃﾌﾔﾂB#ｿAｵﾛ$#ｾｴ#ﾑBｶｼAﾌ#ｹｵｿﾃB$
4470 DATA Lﾗｲﾇ#ｺﾃｹ1ﾟﾝﾉ#ﾔﾑAｩ#ｸｽｿﾃ#ｹBﾇ#ﾙ1ﾒｾｹ#ﾉAｼBAﾉ#ﾈｲﾆ#ﾉｼBｺﾜﾇﾍﾈ1
4480 DATA EｸﾖｵﾃBｿﾃ1ﾑBｻﾍ#ｹBﾇ1ﾒｸｶｻBAｹB#ﾁｹｵｩ#ﾁｵﾍﾀﾜﾌﾉ#ｽｶｼAｿﾃ#ﾏBｿｱｶ1
4490 DATA LﾉAｼBAﾇ#ﾒﾖﾌﾌ#ｴｵﾃBﾉ#ｶﾒﾝｿ#ｺｾﾒﾈﾛﾌ#ｾｻﾛｯｻｹ111ﾓｽBﾇﾆBｴｲﾃﾂB1
4500 DATA Eｴｴ#ｸﾖｵﾃBｿﾃﾁB$#ﾒｸｶﾙ#ｸﾝﾍ#ｹｷｲﾆｺﾃ$#ﾁｹｵﾍ#ｸﾝﾌﾖﾌﾃB$#ｺBｯﾍﾍ$
4510 DATA MﾈｹﾒﾃﾄｹB#ｴﾅﾒｲﾆｺﾃ1ｸﾂﾝﾉ#ﾓﾄﾃ#ﾎﾇﾓﾆB#ｴﾈﾃｩ#ﾓﾅﾕﾆｵﾜ1
4520 DATA EﾇBｶﾃB#ﾒｸｶﾙ$#ｸﾝﾌ#ﾟｾBｩ#ｶｼﾃ#ｹAﾂｶﾍ$#111ﾐｲ#ｿAﾃBｹﾚ#ｺｽｷﾋｷｹ1
4530 DATA FﾂAﾈ111ｴﾈﾃｹB#ﾒｸｶﾌ#ﾂｲｺA#ﾃBｲﾃﾈAﾆ1ｸﾋｹBｵ#ﾖﾇﾉ#ﾖﾇBｲﾆ$
4540 DATA EﾄｱｶﾇBｵｵ1ﾝｿBﾀﾃAﾀ#ﾇBﾖﾕ1ﾕｾBﾟﾛﾈ#ｺｾﾒﾚｩ#ﾒﾀBﾍ#ﾎﾋﾛﾅﾏBｿﾆﾗﾜ$
4550 DATA Eｶｬ111?#ﾈ#ﾈAﾃB$?#ｹﾚﾃBｹB#ﾏBAﾝﾅﾀﾜ111$#ｶｺBｯｴｴｴｲ$$
4560 DATA Mｴﾈﾃﾃﾄﾍ#ｴﾈﾃﾃBｲﾃ#ｿBｯｴｻﾈ#ﾒﾖﾌ#ｹBﾇ#ｩ#ﾃｸｿﾃ1
4570 DATA Fﾙｹｲﾃ#ｽﾝﾆB#ﾁｹｵﾍ#ﾀｻﾟﾝﾃﾟ$#ｴﾛｹBﾇｶ#ﾓAﾈ$
4580 DATA GﾑBｻﾍ#ｽｺｱｶﾉ#ﾉｿｺｩ#ｹｾBﾛﾉ#ｵｻﾂB$
4590 DATA Hﾂｶｹ#ﾝｿBﾀﾃAﾀﾍ#ｽﾝﾆB#ﾎﾇﾒﾀB#ｹｵｾA#ﾈAﾃBﾈ1ｾﾎBｿｵﾙ1
4600 DATA Iｸﾝｾﾒﾃﾄﾍ#ﾁAﾘｶﾃB1ﾒﾃ#ﾈﾉｹ#ｸｺﾃﾚ#ｹｼﾅｼﾜｾ1
4610 DATA Jｸﾝﾍ#ﾖｲﾇ#ｿ-ｺBｱｶｿﾆ#ｵﾞｵﾞﾈ#ﾀｺﾜｩ#ｹｻﾇｻ#ﾀﾜｹﾈ1
4620 DATA KﾑBｶｼAﾌ#ｸﾟﾛﾍ#ﾈAﾃBｹ#ﾁﾅﾈｵﾈ#ｿAｵﾛ$#111ﾖｶ#ﾐBﾆﾚAｹ1
4630 DATA Mｹｻｿﾆ#ﾈｹBｺ#ﾃﾃｹｵﾌ#ﾃﾎBｿBﾍ#ｸﾟｲﾃ1
4640 DATA Mｴﾈﾃﾍ#ﾐｵﾟｩ#ﾇﾛﾖﾇBｿﾃ#ｷｵﾘｶﾇｿﾆ#ﾈｹBｻ#ｹﾃﾛﾅｹBﾝﾆ#ﾘｻｽﾇﾃBﾞｶ1
4650 DATA EﾀﾐBﾆﾍ#ﾒﾛｹB#ﾑBｻｩ#ﾓﾅｼﾆ#ｼｹBｩ#ﾈｸｿﾆｻﾝﾃｹﾚﾃB1ｴﾛｹBﾇｶ1
4660 DATA Fﾏﾏﾏ#ﾇBｶｵﾃｿﾒｿﾆ1ﾋｷ#ｽﾌｴﾇ#ﾘｻｴﾆﾍ#ｴﾜﾌ?
4670 DATA EｶｶA1ﾇｻﾉ#ﾈｵAﾃB1ｽｺｱｶﾖ#ﾈｵｿ1ﾒﾛ#ｺﾓﾌ#ﾏﾜｾﾇﾐ#ｵｲﾃﾚ#ﾃBﾕｹﾈ?
4680 DATA FﾂﾝｹB#ｴﾈﾃﾌ#ﾘｺﾃｵﾇｽﾞﾈﾚ#ﾙﾞｽAﾆB$#ｹAｼBｵﾀﾜﾟ$
4690 DATA Mｴﾈﾃﾍ#ﾒﾛｩ#ﾇﾖﾈｲﾆ#ﾈｹﾒﾃﾄﾉ#ﾟｹﾝｩ#ﾅｼBﾜ1
4700 DATA Mﾒﾃ#ｵﾅｹ1ｽAﾇBﾍ#ﾃﾌｿｵ#ﾙｶｿBﾆB#ｹﾈﾚﾀB#ｴｸｶﾇ#ﾗｻﾂｻｿﾆ111