ここにも書いてます
申請の形式を間違えて今日、再申請になった記念！
公式のタグリファレンスがわかる方じゃないとわからない書き方しかできません！
問い合わされても答える自信もない！
与保比良莅と辻末杳哉
↑これのやり方の覚書です。表題の通りです。
下にあるキャプチャ画像は微調整後なので動画と違います。
まずメッセージレイヤに設定する画像を三つ用意します↓
以下、スクリプト！
*start
[cm]
@clearstack
;ゲームスタート時の背景を出す
[bg storage="b1.jpg" time="100"]
;メッセージウィンドウの非表示(メッセージレイヤ0)
@layopt layer=message0 visible=false
;このゲームで登場するキャラクターを宣言
;youya
[chara_new name="youya" storage="youya1.png" jname="杳哉" ]
;キャラクターの表情登録
[chara_face name="youya" face="smile" storage="youya0.png"]
;hirariヒラリの宣言
[chara_new name="hirari" storage="hirari0.png" jname="比良莅" ]
;ヒラリの表情登録
[chara_face name="hirari" face="dakara" storage="hirari1.png"]
;メッセージレイヤ0の大きさ、透明度、位置、使用する画像の設定
[position layer="message0" left="87" top="42" width="230" height="530" frame="frame.png" opacity="255" vertical="true"]
;文字が表示される領域を調整
[position layer=message0 page=fore margint="60" marginl="100" marginr="100" marginb="60"]
;メッセージレイヤ0に表示される文字色の指定
[font color="black"]
;グリフの位置の設定※ページクリックしてね！のマークのこと
[glyph line="nextpage.png" fix="true" left="180" top="520" color="0x8b4513"]
;レイヤ0、1、文字の表示をnowaitにして最後にメッセージレイヤ0を可視にする
@layopt layer=0 visible=true
@layopt layer=1 visible=true
[nowait]
[position layer="message0" page=fore visible=true]
コーヒーの香りは静かだ。
@p
;次のメッセージレイヤ0の余白調整
[position layer=message0 page=fore margint="60" marginl="100" marginr="70" marginb="60"]
[bg storage="b2.jpg" time="100"]
おいしいのってきけば、[r]
おいしいよって。
@p
;次のメッセージレイヤ0の余白調整
[position layer=message0 page=fore margint="60" marginl="100" marginr="100" marginb="60"]
[bg storage="b3.jpg" time="100"]
そうなの？
@p
～省略～
;メッセージウィンドウの非表示
@layopt layer=message0 visible=false time=10
;背景を切り替えてキャラ表示
[bg storage="b1.jpg" time="100"]
@chara_show name=youya time=10
@chara_show name=hirari time=10
;グリフの位置調整;
[glyph fix="true" line="nextpage.png" left="1100" top="500" color="0x8b4513"]
;メッセージレイヤ0の設定※ようや(男)の吹き出しのこと。余白は設定しなおさなくていいと判断
[position layer="message0" left="950" top="15" width="300" height="560" frame="frame2.png" opacity="255" vertical="true"]
;メッセージレイヤの表示
@layopt layer=message0 visible=true time=10
※↓こうなります
#youya
飲んだの？
@p
[chara_mod name=youya face="smile" time="10" cross="false"]
どうだった？
@p
#
;メッセージウィンドウの非表示
@layopt layer=message0 visible=false time=10
;グリフの位置設定
[glyph fix="true" line="nextpage.png" left="140" top="470" color="0x8b4513"]
;メッセージレイヤ0の設定（ヒラリ(女)の吹き出しのこと。余白は設定しなおさなくていいと判断
[position layer="message0" left="45" top="135" width="245" height="400" frame="frame3.png" opacity="255" vertical="true"]
;メッセージレイヤの表示
[position layer="message0" page=fore visible=true]
※↓こうなります
#hirari
おいしくない。
@p
[chara_mod name=hirari face="dakara" time="10" cross="false"]
だから ……
@p
#
@chara_hide_all time=10
;メッセージウィンドウの非表示
@layopt layer=message0 visible=false
;背景レイヤにフィルターをかけてぼやけさせる
@filter layer="base" blur="5"
@image layer=1 storage=asi.jpg left=370 top=35
@wait time=2000
@free_filter layer="base"
@freeimage layer=1
@bg storage=b.jpg time=10
;メッセージレイヤ0の設定。(しかくの吹き出し
[position layer="message0" left="87" top="42" width="230" height="530" frame="frame.png" opacity="255" vertical="true"]
;グリフの位置設定
[glyph fix="true" line="nextpage.png" left="180" top="520" color="0x8b4513"]
;メッセージレイヤの表示
[position layer="message0" page=fore visible=true]
@image layer=1 storage=hart.png left=1080 top=290
コーヒーの香りは甘い。
@p
@freeimage layer=1
@bg storage=black.jpg time=10