Mask

var myMask:MyMask = new MyMask();



addChild(myMask);  //myMaskもディスプレーツリーに登録



var myObj:MyObj = new Obj();



myObj.mask = myMask;



addChild(myObj);

リンクボタンas

addEventListener(MouseEvent.CLICK,xlink);
function xlink (event:MouseEvent) :void{
var theURLL:URLRequest = new URLRequest("http://A");
navigateToURL(theURLL , "_parent");
}

16.グラデーション塗り

package {
import flash.display.GradientType;
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.geom.Matrix;

public class GradientFill extends Sprite {
public function GradientFill() {

init();
}
private function init():void {
//cord;
graphics.lineStyle(0);
var colors:Array = [0xff00ff , 0xff0000];
var alphas:Array = [1 ,1];
var rations:Array = [0 , 255];
var matrix:Matrix = new Matrix();
matrix.createGradientBox(100 , 100 ,0,0,0);
graphics.beginGradientFill(GradientType.LINEAR , colors , alphas , rations , matrix);
graphics.drawRect(0,0,100,100);
graphics.endFill();
}
}
}

15.連続した曲線

package {
import flash.display.Sprite;
public class MultiCurve extends Sprite {
private var numpoints:uint = 11;
public function MultiCurve() {

init();
}
private function init():void {
//cord;
var points:Array = new Array();
for(var i:int = 0 ; i<numpoints ; i++){
points[i] = new Object();
points[i].x = Math.random()*stage.stageHeight;
points[i].y = Math.random()*stage.stageHeight;
}
graphics.lineStyle(1);
graphics.moveTo(points[0].x , points[0].y);

for(i = 1;i<numpoints -2 ; i++ ){
var xc:Number = (points[i].x + points[i + 1].x) / 2;
var yc:Number = (points[i].y + points[i + 1].y) / 2;
graphics.curveTo(points[i].x , points[i].y , xc , yc);
}
graphics.curveTo(points[i].x , points[i].y ,points[i].x , points[i].y);
}
}
}

14.曲線

package {
import flash.display.Sprite;
import flash.events.MouseEvent;

public class DrawingCurve extends Sprite {
private var x0:Number = 100;
private var y0:Number = 200;
private var x1:Number;
private var y1:Number;
private var x2:Number = 300;
private var y2:Number = 200;

public function DrawingCurve() {
init();
}
private function init():void {
//cord;
stage.addEventListener(MouseEvent.MOUSE_MOVE , onMouseMove);
}
private function onMouseMove(event:MouseEvent):void{
x1 = mouseX*2 - (x0 + x2)/2;
y1 = mouseY*2 - (y0 + y2)/2;
graphics.clear();
graphics.lineStyle(1);
graphics.moveTo(x0,y0);
graphics.curveTo(x1,y1,x2,y2);
}
}
}

13.マウスで線を書く

package {
import flash.display.Sprite;
import flash.events.MouseEvent;

public class Drawing extends Sprite {
public function Drawing() {
init();
}
private function init():void {
//cord;
graphics.lineStyle(1);
stage.addEventListener(MouseEvent.MOUSE_DOWN , onMouseDown);
stage.addEventListener(MouseEvent.MOUSE_UP , onMouseUp);
}
private function onMouseDown(event:MouseEvent):void{
graphics.moveTo(mouseX,mouseY);
stage.addEventListener(MouseEvent.MOUSE_MOVE , onMouseMove);
}
private function onMouseUp(event:MouseEvent):void{
stage.removeEventListener(MouseEvent.MOUSE_MOVE , onMouseMove);
}
private function onMouseMove(event:MouseEvent):void{
graphics.lineTo(mouseX,mouseY);
}
}
}

12.中心からマウスまでの距離

package {
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.text.TextField;

public class MouseDistance extends Sprite {
private var sprite1:Sprite;
private var textFeild:TextField;
public function MouseDistance() {
init();
}

private function init():void {
//cord;
sprite1 = new Sprite();
addChild(sprite1);
sprite1.graphics.beginFill(0xff0000);
sprite1.graphics.drawRect(-2,-2,4,4);
sprite1.graphics.endFill();
sprite1.x = stage.stageWidth/2;
sprite1.y = stage.stageHeight/2;

textFeild = new TextField();
addChild(textFeild);
stage.addEventListener(MouseEvent.MOUSE_MOVE , onenterframe);
}
public function onenterframe(event:MouseEvent):void{
graphics.clear();
graphics.lineStyle(1,0,1);
graphics.moveTo(sprite1.x ,sprite1.y);
graphics.lineTo(mouseX,mouseY)
var dx:Number = sprite1.x -mouseX;
var dy:Number = sprite1.y -mouseY;
var dist:Number = Math.sqrt(dx*dx + dy*dy);
textFeild.text = dist.toString();

}
}
}

11.2点間の距離

package {
import flash.display.Sprite;
public class Distance extends Sprite {
public function Distance() {
init();
}
private function init():void {
//cord;
var sprite1:Sprite = new Sprite();
addChild(sprite1);
sprite1.graphics.beginFill(0xff0000);
sprite1.graphics.drawRect(-2,-2,4,4);
sprite1.graphics.endFill();
sprite1.x = Math.random()*stage.stageWidth/2;
sprite1.y = Math.random()*stage.stageHeight/2;

var sprite2:Sprite = new Sprite();
addChild(sprite2);
sprite2.graphics.beginFill(0xff0000);
sprite2.graphics.drawRect(-2,-2,4,4);
sprite2.graphics.endFill();
sprite2.x = Math.random()*stage.stageWidth/2;
sprite2.y = Math.random()*stage.stageHeight/2;

var dx:Number = sprite1.x -sprite2.x;
var dy:Number = sprite1.y -sprite2.y;
var dist:Number = Math.sqrt(dx*dx + dy*dy);
trace(dist);

}
}
}

10.楕円を描く

楕円運動

package {
import flash.display.Sprite;
import flash.events.Event;

public class Oval extends Sprite {
private var ball:Ball;
private var angle:Number=0;
private var centerX:Number = 200;
private var centerY:Number = 200;
private var radiusX:Number = 200;
private var radiusY:Number = 100;
private var speed:Number = .1;

public function Oval() {
init();
}
private function init():void {
//cord;
ball = new Ball();
addChild(ball);
ball.x = 0;
addEventListener(Event.ENTER_FRAME , onenterframe);
}
public function onenterframe (event:Event):void {
ball.x = centerX + Math.sin(angle)*radiusX;
ball.y = centerY + Math.cos(angle)*radiusY;
angle += speed;

}
}
}

09.circle

円運動

package {
import flash.display.Sprite;
import flash.events.Event;

public class Circle extends Sprite {
private var ball:Ball;
private var angle:Number=0;
private var centerX:Number = 200;
private var centerY:Number = 200;
private var radius:Number = 100;
private var speed:Number = .1;

public function Circle() {
init();
}
private function init():void {
//cord;
ball = new Ball();
addChild(ball);
ball.x = 0;
addEventListener(Event.ENTER_FRAME , onenterframe);
}
public function onenterframe (event:Event):void {
ball.x = centerX + Math.cos(angle)*radius;
ball.y = centerY + Math.sin(angle)*radius;
angle += speed;

}
}
}