N88-BASICで宇宙(1回目 所要時間)
地球の自転速度 = 赤道半径×2π / 自転周期
= 6378.1km ･ 2π / 23時間56分4.100秒
= 6378.1km ･ 2･3.141593 / (86164.1/3600)h
= 1674.3543… km/h
ほぼ円軌道なので軌道半径≒軌道長半径として
地球の公転速度 = 軌道半径×2π / 公転周期
= 1AU×2π / 1年
= 149597870.700km×2π / (365.2422×24)h
= 107229.2174… ≒ 10.7万 km/h
水星の公転速度 = 軌道半径×2π / 公転周期
= 5790万km×2π / (0.24085×365.25×24)h
= 17.2309952… ≒ 17万 km/h
歩き = 約4 km/h
新幹線 = 約300 km/h
地球の自転速度 = 約1600 km/h
スペースシャトル = 約28000 km/h
地球の公転速度 = 約10万 km/h
水星の公転速度 = 約17万 km/h
(少なく見積もっています)
で、太陽から各惑星までの所要時間を
光速の場合と比較表示しました
NL-BASICとnl30603.zip(spc001.bas)は
以下のリンクからダウンロードできます
Readme.txtを読んで遊んで下さい
下記リストをマウスで選択しCtrl+cでコピーし、
NL-BASICの画面でAlt+v(Ctrl+vではないので注意)
でプログラムを読込めます。
spc001.bas
100 '---------------------------------------------------------------------
110 ' 宇宙
120 '
130 ' 2021.5 by ULproject for N88-BASIC, NL-BASIC
140 '---------------------------------------------------------------------
150 DEFDBL A-H, J-Z: DEFINT I
160 '---------------------------------------------------------------------
170 ' 天文単位AU(km), 光速度Lv(km/s) , 軌道長半径a(AU)
180 AU = 149597870.700
190 LV = 299792.458
200 DATA "水星", "金星","地球", "火星", "木星", "土星", "天王星","海王星"
210 DATA 0.3871, 0.7233, 1.0 , 1.5237, 5.2026, 9.5549, 19.2184 , 30.1104
220 '---------------------------------------------------------------------
230 DIM A(8)
240 A(0) = 0
250 FOR I = 1 TO 8
260 READ P$(I)
270 NEXT
280 FOR I = 1 TO 8
290 READ A(I)
300 NEXT
310 '---
320 INPUT "速度(km/h) = "; V
330 IF V <= 0 THEN V = LV * 3600
340 PV = V / 3600
350 U$ = " 光速, ############,(km/h)"
360 PRINT USING U$; V
370 U$ = "& &, ##.##AU, ##.##億km, #:##:##"
380 FOR I = 1 TO 8
390 X = A(I) * AU
400 Z = X / 1E+8
410 T = X / LV
420 GOSUB *HMS
430 PRINT USING U$; P$(I), A(I), Z, H, M, S;
440 T = X / PV
450 GOSUB *HMS
460 GOSUB *YD
470 PRINT USING ", ######年###日##:##:##"; Y, D, H, M, S
480 NEXT
490 END
500 '--- h:m:s(t)
510 *HMS
520 U = FIX(T / 60)
530 S = T - U * 60
540 H = FIX(U / 60)
550 M = U - H * 60
560 RETURN
570 '--- y:d(h)
580 *YD
590 U = FIX(H / 24)
600 H = H - U * 24
610 Y = FIX(U / 365)
620 D = U - Y * 365
630 RETURN