BASICで万有引力 (2回目火星の重力)

前回は3体に働く万有引力のシミュレートを

しましたが

今回は惑星などの表面の重力の計算です

(遠心力は無視し惑星を球とした近似値です)

万有引力定数(重力定数)G(Nmm/kgkg)

惑星の質量M(kg)

人の質量m(m)

Mとmの中心間距離r(m)

万有引力F(N)

F = GMm/r²

等速円運動

角速度ω(rad/s)

時間(s)

半径r(m)

位置ベクトル

R = (rcosωt, rsinωt)

速度ベクトル

V = dR/dt = (-rsinωt, rcosωt)ω

加速度ベクトル

A = dV/dt = -(rcosωt, rsinωt)ω²

= -Rω²

A//Rよりa = |A| = -|R|ω² = -rω²

向心力F''= ma = -mrω²

慣性の法則より遠心力F' = -F'' = mrω²

(エレベーターが上向きに加速するとき

下向きの力を感じるのと同じです)

赤道の重力加速度g

= (F - F')/m = GM/r² - rω²

相対的な重力加速度(G)は赤道での値です

重力加速度は万有引力と遠心力を分けて

表示しています

計算値はおおよその値として楽しんで

下さい

火星の重力は地球の約38%ほどです

惑星などのデータは

理科年表2020年(国立天文台)

参照です

NL-BASICとnl30222.zip(grav002.bas)は

以下のリンクからダウンロードできます

NL-BASIC(N88-BASIC互換?)ホームページ

Readme.txtを読んで遊んで下さい

下記リストをマウスで選択しCtrl+cでコピーし、

NL-BASICの画面でAlt+v(Ctrl+vではないので注意)

でプログラムを読込めます。

grav002.bas

100 '----------------------------------------------------------------------
110 ' BASICで万有引力 (2回目) by ULproject 2021.2.22(月)
120 '
130 ' 惑星などの表面の重力
140 '----------------------------------------------------------------------
150 PI = ATN(1) * 4
160 '---
170 READ G
180 READ ME
190 READ N
200 N = N - 1
210 DIM R(N), M(N), D(N), NAME$(N), A(N), F(N)
220 FOR I=0 TO N
230 READ R(I), M(I), D(I), NAME$(I)
240 B = R(I) * 1E+3 '--- 半径(m)
250 A(I) = G * M(I) * ME / (B * B) '--- g(m/ss)(遠心力なし)
260 C = D(I) * 24 * 3600 '--- 周期(s)
270 C = (2 * PI) / C '--- 角速度ω(rad/s)
280 F(I) = B * C * C '--- (遠心力mrωω)/m
290 NEXT
300 '---
310 GE = A(3) - F(3)
320 FOR I=0 TO N
330 B = A(I)
340 C = F(I)
350 PRINT USING "###.# _-##.#^^^^ m/ss"; B, C;
360 B = (B - C) / GE
370 PRINT USING " ##.#^^^^ G @"; B, NAME$(I)
380 NEXT
390 END
400 '--- 惑星などのData
410 DATA 6.67428e-11 '--- 重力定数(Nmm/kglg)
420 DATA 5.972E+24 '--- 地球の質量(kg)
430 DATA 10 '--- 惑星などの数
440 '--- 赤道半径相対質量自転周期名称
450 '--- (km) (地球基準) (日)
460 DATA 696000 , 332946 , 25.3800, "太陽"
470 DATA 2439.7, 0.05527 , 58.6462, "水星"
480 DATA 6051.8, 0.8150 , 243.0185, "金星"
490 DATA 6378.1, 1.0000 , 0.9973, "地球"
500 DATA 3396.2, 0.1074 , 1.0260, "火星"
510 DATA 71492 , 317.83 , 0.4135, "木星"
520 DATA 60268 , 95.16 , 0.4440, "土星"
530 DATA 25559 , 14.54 , 0.7183, "天王星"
540 DATA 24764 , 17.15 , 0.6712, "海王星"
550 DATA 1737.4, 0.012300, 27.3217, "月"

BASICで万有引力 (2回目 火星の重力)

BASICで万有引力 (2回目火星の重力)