サブキャラなど、キャラクター数が増えるとわずらわしくなるのがログイン作業です。

仮に次のようなキャラクタ名とアカウント、パスワードがあったとしましょう。

キャラクタ名	アカウント	パスワード
メンバーＡ	abc.def@hehe.jp	123
メンバーＢ	ABC-jp	456
メンバーＣ	abc_def	7890

マクロを実行すると、メモ帳に次のようなキャラクター選択肢が出て、

メンバーID (1～2) を入力すると、あとは勝手にログインしてくれるようにすると楽ですよね。

『ログイン(サンプル).uws』

// グローバル変数

Public IEID

Public IEobj

// 画面基準点

// アカウント入力

DIM xyTextBoxAccount[2] = 244,434

// パスワード入力

DIM xyTextBoxPassword[2] = 244,469

// サーバー選択プルダウン

DIM xyPullDownServer[2] = 345,503

// サーバー選択

DIM xySelectServer[2] = 290,670

// ゲームスタート

DIM xyGameStart[2] = 225,580

// IEのハンドルを取得

//IEID = GETID("Windows Internet Explorer")

IEID = GETID("Internet Explorer")

if IEID < 0 then

  FUKIDASI("IE not found.")

  Sleep(1)

  FUKIDASI("")

else

  // IEのオブジェクトを取得

  IEobj = GETACTIVEOLEOBJ("InternetExplorer.Application")

endif

// メモ帳を開く

notepadID = GETID("メモ帳",, 0.1)

if notepadID < 0 then

  // "メモ帳" でヒットしない場合は "Notepad" を試してみる

  notepadID = GETID("Notepad",, 0.1)

  if notepadID < 0 then

    // それでもダメなら新しく "メモ帳" を開く

    notepadID = EXEC(GET_SYS_DIR+"\notepad.exe", False, 800, 10, 400, 300)

    Sleep(0.5)

  endif

endif

// メモ帳をクリアする

SendStr(notepadID, "", 1, TRUE)

Sleep(0.5)

// main処理の開始

// メモ帳にユーザー名と memberID を表示

sendstr(notepadID, "1, メンバーＡ<#CR>")

sendstr(notepadID, "2, メンバーＢ<#CR>")

sendstr(notepadID, "3, メンバーＣ<#CR>")

memberID = input("memberIDを入力してください")

if memberID = "" then

  // 入力がなかったらキャンセル

  sendstr(notepadID, "キャンセルされました。<#CR>")

elseif chknum( memberID ) then

  // 入力が数値だったら、ログインを実行

  if ( 0 < memberID ) and ( memberID < 4 )

    // アカウント入力のテキストボックスにフォーカス

    MMV(xyTextBoxAccount[0],xyTextBoxAccount[1])

    sleep(0.2)

    BTN(LEFT, CLICK)

    BusyWait(1)

    BTN(LEFT, CLICK)

    BusyWait(1)

    // アカウント名の入力

    writeAccount(memberID)

    sleep(0.2)

    // パスワード入力のテキストボックスにフォーカス

    MMV(xyTextBoxPassword[0],xyTextBoxPassword[1])

    sleep(0.2)

    BTN(LEFT, CLICK)

    BusyWait(1)

    BTN(LEFT, CLICK)

    BusyWait(1)

    // パスワード名の入力

    writePassword(memberID)

    sleep(0.2)

    // サーバー選択プルダウンをクリック

    MMV(xyPullDownServer[0],xyPullDownServer[1])

    sleep(0.5)

    BTN(LEFT, CLICK)

    BusyWait(1)

    // サーバー選択をクリック

    sleep(0.2)

    MMV(xySelectServer[0],xySelectServer[1])

    sleep(0.2)

    BTN(LEFT, CLICK)

    BusyWait(1)

    // ゲームスタートをクリック

    sleep(0.2)

    MMV(xyGameStart[0],xyGameStart[1])

    sleep(0.2)

    BTN(LEFT, CLICK)

    BusyWait(1)

  else

    sendstr(notepadID, "memberID=("+memberID+")が範囲外です。<#CR>")

  endif

else

  sendstr(notepadID, "数値ではありません。<#CR>")

endif

// main処理の終了

// サブルーチン

//------

Procedure BusyWait(count)

  if IEID < 0 then

    // IEのハンドルが取得できなかった場合は

    // 指定の秒数をスリープ

    Sleep(count)

  else

    Sleep(0.5)

    // busyフラグが落ちるまでリピート

    repeat

      Sleep(0.2)

//    until (! IEobj.busy) and (IEobj.readyState=4)

    until (IEobj.readyState=4)

//    until (! IEobj.busy)

    Sleep(0.5)

  endif

Fend

//------

// アカウントを入力する

Procedure writeAccount(num)

  // (num=1): abc.def@hehe.jp

  DIM acc_txt1[] = VK_A, VK_B, VK_C, VK_DECIMAL, VK_D, VK_E, VK_F, VK_OEM_3, VK_H, VK_E, VK_H, VK_E, VK_DECIMAL, VK_J, VK_P // 15文字

  // (num=2): ABC-jp

  DIM acc_txt2[] = VK_CAPITAL, VK_A, VK_B, VK_C, VK_CAPITAL, VK_SUBTRACT, VK_J, VK_P // 8文字

  // (num=3): abc_def // アンダーバーは別扱い

  DIM acc_txt3_1[] = VK_A, VK_B, VK_C // 3文字

  DIM acc_txt3_2[] = VK_D, VK_E, VK_F // 3文字

  if num = 1 then

    for i = 0 to (15-1)

      KBD(acc_txt1[i])

    next

  elseif num = 2 then

    for i = 0 to (8-1)

      KBD(acc_txt2[i])

    next

  elseif num = 3 then

    for i = 0 to (3-1)

      KBD(acc_txt3_1[i])

    next

    // アンダーバー

    KBD(VK_SHIFT,down,10)

    KBD(VK_OEM_102,click,10)

    KBD(VK_SHIFT,up,10)

    for i = 0 to (3-1)

      KBD(acc_txt3_2[i])

    next

  endif

Fend

//------

// パスワードを入力する

Procedure writePassword(num)

  // (num=1): 123

  DIM pass_txt1[] = VK_1, VK_2, VK_3 // 3文字

  // (num=2): 456

  DIM pass_txt2[] = VK_4, VK_5, VK_6 // 3文字

  // (num=3): 7890

  DIM pass_txt3[] = VK_7, VK_8, VK_9, VK_0 // 4文字

  if num = 1 then

    for i = 0 to (3-1)

      KBD(pass_txt1[i])

    next

  elseif num = 2 then

    for i = 0 to (3-1)

      KBD(pass_txt2[i])

    next

  elseif num = 3 then

    for i = 0 to (4-1)

      KBD(pass_txt3[i])

    next

  endif

Fend

まず、上記の枠内を『ログイン(サンプル).uws』のような名前でファイルにセーブしてください。
その後、位置合わせのために以下のパラメータを環境に合わせて変更してください。

// 画面基準点

// アカウント入力

DIM xyTextBoxAccount[2] = 244,434

// パスワード入力

DIM xyTextBoxPassword[2] = 244,469

// サーバー選択プルダウン

DIM xyPullDownServer[2] = 345,503

// サーバー選択

DIM xySelectServer[2] = 290,670

// ゲームスタート

DIM xyGameStart[2] = 225,580

ログインマクロを使う場合、キャラクタに合わせてアカウントやパスワードを変更して使う事になると思いますが、
修正した後は、いきなり Internet Explorer のログイン画面でテストするのではなく、
キーボード出力される位置にメモ帳のような白紙のエディタを置いておいて、期待する文字列が出力されるかを試すのが良いでしょう。