標準偏差 や ADX で、トレンドの強弱を表示したくても
いつも手遅れって感じになるから使わない人も多い
特に、ADX はうちのメンバーだれも使ってない
もしかすると、自分の書き換えたインジケータが間違え
てるんじゃないかと思ったりするけど
まぁ間違えてたら、また書き直せばいいだけの話だから
気にしないで ↓ に
一応、ワイルダー式とそうじゃないのとを切り替え出来る
ようにしてあるから後は適当に・・・
//+----------------------+
//| Wat_ADX2.mq4 |
//+----------------------+
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_color1 Magenta
#property indicator_width1 1
#property indicator_color2 Magenta
#property indicator_width2 1
//---- input parameters
extern int ADXPeriod=14;
extern int MAmode =MODE_EMA; //
extern bool Wilder=true;
//---- buffers
double ADXBuffer[];
double UpBuffer[];
double PlusDiBuffer[];
double MinusDiBuffer[];
double PlusSdiBuffer[];
double MinusSdiBuffer[];
double TempBuffer[];
int CutLine=25;
double ap;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int init()
{
//---- 3 additional buffers are used for counting.
IndicatorBuffers(7);
//---- indicator buffers
SetIndexBuffer(0,ADXBuffer);
SetIndexBuffer(1,UpBuffer);
SetIndexBuffer(2,PlusDiBuffer);
SetIndexBuffer(3,MinusDiBuffer);
SetIndexBuffer(4,PlusSdiBuffer);
SetIndexBuffer(5,MinusSdiBuffer);
SetIndexBuffer(6,TempBuffer);
SetIndexStyle(0,DRAW_LINE);
SetIndexStyle(1,DRAW_ARROW); SetIndexArrow(1,159);
//---- name for DataWindow and indicator subwindow label
IndicatorShortName("Wat_ADX2("+ADXPeriod+")");
SetIndexLabel(0,"ADX");
//----
SetIndexDrawBegin(0,ADXPeriod);
SetIndexDrawBegin(1,ADXPeriod);
//----
ap = ADXPeriod;
SetLevelStyle(STYLE_DOT, 0, Red);
if(Wilder==true) {
ap=ADXPeriod*2-1;
CutLine = 10;
SetLevelValue(0, 15);
SetLevelValue(1, 40);
} else {
SetLevelValue(0, CutLine);
SetLevelValue(1, 50);
}
//----
return(0);
}
//+------------------------------------------------------------------+
//| Average Directional Movement Index |
//+------------------------------------------------------------------+
int start()
{
double pdm,mdm,tr;
double price_high,price_low;
double p, q; //trend[],
int starti,i,counted_bars=IndicatorCounted();
//----
i=Bars-2;
PlusSdiBuffer[i+1]=0;
MinusSdiBuffer[i+1]=0;
if(counted_bars>=i) i=Bars-counted_bars-1;
starti=i;
//----
while(i>=0) {
price_low=Low[i];
price_high=High[i];
//----
pdm=price_high-High[i+1];
mdm=Low[i+1]-price_low;
if(pdm<0) pdm=0; // +DM
if(mdm<0) mdm=0; // -DM
if(pdm==mdm) { pdm=0; mdm=0;}
if(pdm<mdm) pdm=0;
if(mdm<pdm) mdm=0;
//----
double num1=MathAbs(price_high-price_low);
double num2=MathAbs(price_high-Close[i+1]);
double num3=MathAbs(price_low-Close[i+1]);
tr=MathMax(num1,num2);
tr=MathMax(tr,num3);
//---- counting plus/minus direction
if(tr==0) { PlusSdiBuffer[i]=0; MinusSdiBuffer[i]=0; }
else { PlusSdiBuffer[i]=100.0*pdm/tr; MinusSdiBuffer[i]=100.0*mdm/tr; }
//----
i--;
}
//---- last counted bar will be recounted
if(counted_bars>0) counted_bars--;
int limit=Bars-counted_bars;
//---- apply EMA to +DI
for(i=0; i<=limit; i++) PlusDiBuffer[i]=iMAOnArray(PlusSdiBuffer,Bars,ap,0,MAmode,i);
//---- apply EMA to -DI
for(i=0; i<=limit; i++) MinusDiBuffer[i]=iMAOnArray(MinusSdiBuffer,Bars,ap,0,MAmode,i);
//---- Directional Movement (DX)
i=Bars-2;
TempBuffer[i+1]=0;
i=starti;
while(i>=0) {
double div=MathAbs(PlusDiBuffer[i]+MinusDiBuffer[i]);
if(div==0.00) TempBuffer[i]=0;
else TempBuffer[i]=100*(MathAbs(PlusDiBuffer[i]-MinusDiBuffer[i])/div);
i--;
}
//---- ADX is exponential moving average on DX
for(i=0; i<limit; i++) ADXBuffer[i]=iMAOnArray(TempBuffer,Bars,ap,0,MAmode,i);
for(i=0; i<limit; i++) {
if(ADXBuffer[i]>ADXBuffer[i+1] && ADXBuffer[i]>CutLine) UpBuffer[i] = ADXBuffer[i];
else UpBuffer[i] = EMPTY_VALUE;
}
//----
return(0);
}
//+----------------------------------------------+
今は凪の時間 USD/JPY ５分足
ADX（ 細いピンク )もStdDev( 黄 )も揃って
下降中
